LB_ADDSTRING Message

Platforms

Windows 95: Supported.
Windows 98: Supported.
Windows NT: Requires Windows NT 3.1 or later.
Windows 2000: Supported.
Windows CE: Requires Windows CE 1.0 or later.

Description & Usage

Sending the LB_ADDSTRING message to a list box control adds a string to its list. If the list box is sorted, the new string is added in its proper position according to the sort. If the list box is not sorted, the new string is added to the end. To control where the string is added, use the LB_INSERTSTRING message instead.

Return Value

If successful, the message returns the zero-based index of the newly added string's position in the list box. If there is insufficient space to store the new string, the message returns LB_ERRSTRING. If some other error occurs, the message returns LB_ERR.

Visual Basic-Specific Issues

None.

Parameters

wParam: Not used -- set to 0.
lParam: The string to add to the list box.

Constant Definitions

Const LB_ADDSTRING = &H180
Const LB_ERR = -1
Const LB_ERRSPACE = -2

Example

When the user clicks button Command1, empty the list box List1, and then add three strings to it. The order in which the strings appear will depend on whether the list box is sorted or not.

To use this example, place a list box named List1 and a command button named Command1 on a form window. To verify that the list box's list is being emptied, you may wish to add some items to it before running the example.

' This code is licensed according to the terms and conditions listed here.

' Declarations and such needed for the example:
' (Copy them to the (declarations) section of a module.)
Public Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA" (ByVal hWnd As Long, ByVal Msg _
	As Long, wParam As Any, lParam As Any) As Long
Public Const LB_ADDSTRING = &H180
Public Const LB_RESETCONTENT = &H184

' *** Place the following code inside a form window. ***

Private Sub Command1_Click()
	Dim retval As Long  ' return value
	
	' Empty the list box List1.
	retval = SendMessage(List1.hWnd, LB_RESETCONTENT, ByVal CLng(0), ByVal CLng(0))
	
	' Now add three strings to List.  Their exact placement will
	' depend on whether List1 is sorted or not.
	retval = SendMessage(List1.hWnd, LB_ADDSTRING, ByVal CLng(0), ByVal "First Item Added")
	retval = SendMessage(List1.hWnd, LB_ADDSTRING, ByVal CLng(0), ByVal "Second Item Added")
	retval = SendMessage(List1.hWnd, LB_ADDSTRING, ByVal CLng(0), ByVal "Last Item Added")
End Sub