IPM_SETFOCUS Message

Platforms

Windows 95: Requires Internet Explorer 4.0 or later.
Windows 98: Supported.
Windows NT: Requires Internet Explorer 4.0 or later.
Windows 2000: Supported.
Windows CE: Requires Windows CE 1.0 or later.

Description & Usage

Sending the IPM_SETFOCUS message to an IP Address contol gives the control the keyboard focus. The text in the particular field that is given the focus will automatically be selected.

Return Value

The message does not return a meaningful value.

Visual Basic-Specific Issues

None.

Parameters

wParam: Specifies the (zero-based) field of the control to give the focus to. If this is greater than three, then the focus is set to the first blank field, or the first one if all fields are filled.

Constant Definitions

Const IPM_SETFOCUS = &H468

Example

When the form loads, create an IP Address control and place it in the upper-left corner of the window. When the user clicks button cmdClear, the contents of the IP Address control are erased and the keyboard focus is given to the first field in the control.

To use this example, create a command button named cmdClear and place it on a form window. The IP Address control will be created programmatically when the program starts.

' This code is licensed according to the terms and conditions listed here.

' Declarations and such needed for the example:
' (Copy them to the (declarations) section of a module.)
Public Type INITCOMMONCONTROLSEX_TYPE
	dwSize As Long
	dwICC As Long
End Type
Public Declare Function InitCommonControlsEx Lib "comctl32.dll" (lpInitCtrls As _
	INITCOMMONCONTROLSEX_TYPE) As Long
Public Const ICC_INTERNET_CLASSES = &H800
Public Declare Function CreateWindowEx Lib "user32.dll" Alias "CreateWindowExA" (ByVal dwExStyle As Long, _
	ByVal lpClassName As String, ByVal lpWindowName As String, ByVal dwStyle As Long, ByVal x _
	As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hWndParent As Long, _
	ByVal hMenu As Long, ByVal hInstance As Long, lpParam As Any) As Long
Public Const WC_IPADDRESS = "SysIPAddress32"
Public Const WS_CHILD = &H40000000
Public Const WS_VISIBLE = &H10000000
Public Declare Function DestroyWindow Lib "user32.dll" (ByVal hWnd As Long) As Long
Public Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA" (ByVal hWnd As Long, ByVal Msg _
	As Long, wParam As Any, lParam As Any) As Long
Public Const IPM_CLEARADDRESS = &H464
Public Const IPM_SETFOCUS = &H468

' *** Place the following code inside the form window. ***

Private hIPControl As Long  ' handle to the IP Address control

' When the form is initialized, create an IP Address control in the
' upper-left corner of the form.
Private Sub Form_Initialize()
	Dim comctls As INITCOMMONCONTROLSEX_TYPE  ' identifies the control to register
	Dim retval As Long                        ' generic return value
	
	' Register the IP Address control window class.
	With comctls
		.dwSize = Len(comctls)
		.dwICC = ICC_INTERNET_CLASSES
	End With
	retval = InitCommonControlsEx(comctls)
	
	' Create the IP Address control in the corner of the window.
	hIPControl = CreateWindowEx(0, WC_IPADDRESS, "", WS_CHILD Or WS_VISIBLE, 0, 0, 125, 20, _
		Me.hWnd, 0, App.hInstance, ByVal CLng(0))
End Sub

' Destroy the IP Address control when the form closes.
Private Sub Form_Unload(Cancel As Integer)
	Dim retval As Long  ' return value
	
	retval = DestroyWindow(hIPControl)
End Sub

' Clear the contents of the IP Address control when the
' use clicks this button.
Private Sub cmdClear_Click()
	Dim retval As Long
	
	' Clear the contents of the control.
	retval = SendMessage(hIPControl, IPM_CLEARADDRESS, ByVal CLng(0), ByVal CLng(0))
	' Give the first field (field 0) the keyboard focus.
	retval = SendMessage(hIPControl, IPM_SETFOCUS, ByVal CLng(0), ByVal CLng(0))
End Sub