CB_GETCURSEL Message

Platforms

Windows 95: Supported.
Windows 98: Supported.
Windows NT: Requires Windows NT 3.1 or later.
Windows 2000: Supported.
Windows CE: Requires Windows CE 1.0 or later.

Description & Usage

The CB_GETCURSEL message finds out which list-box item is currently selected in a combo box control. This message only returns useful information if the combo box's selection is one of the items available in its list box portion. If the user types different data into the tex box portion, the function merely reports that no item is selected.

Return Value

The message returns the zero-based index of the selected item (the first item has an index of 0, etc.). If none of the items in the list box portion are selected, the message returns -1.

Visual Basic-Specific Issues

None.

Parameters

wParam: Not used -- set to 0.
lParam: Not used -- set to 0.

Constant Definitions

Const CB_GETCURSEL = &H147

Example

' This code is licensed according to the terms and conditions listed here.

' Declarations and such needed for the example:
' (Copy them to the (declarations) section of a module.)
Public Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA" (ByVal hWnd  _
	As Long, ByVal Msg As Long, wParam As Any, lParam As Any) As Long
Public Const CB_GETCURSEL = &H147
Public Const CB_GETLBTEXT = &H148
Public Const CB_GETLBTEXTLEN = &H149

' Display the text of whatever item in combo box Combo1
' is currently selected.  If no list box item is selected, say so.
Dim index As Long       ' index to the selected item
Dim itemtext As String  ' the text of the selected item
Dim textlen As Long     ' the length of the selected item's text

' Determine the index of the selected item.
index = SendMessage(Combo1.hWnd, CB_GETCURSEL, ByVal CLng(0), ByVal CLng(0))
' Decide what to do based on that.
Select Case index
Case -1    ' No list box item was selected.
	Debug.Print "No list box item in the combo box is selected."
Case Else  ' Some item is selected.
	' Determine how long the item's text is.
	textlen = SendMessage(Combo1.hWnd, CB_GETLBTEXTLEN, ByVal CLng(index), ByVal CLng(0))
	' Make enough room in the string to receive the text, including the terminating null.
	itemtext = Space(textlen) & vbNullChar
	' Retrieve that item's text and display it.
	textlen = SendMessage(Combo1.hWnd, CB_GETLBTEXT, ByVal CLng(index), ByVal itemtext)
	itemtext = Left(itemtext, textlen)
	Debug.Print "Selected item: "; itemtext
End Select