WM_CLOSE Message

Platforms

Windows 95: Supported.
Windows 98: Supported.
Windows NT: Requires Windows NT 3.1 or later.
Windows 2000: Supported.
Windows CE: Requires Windows CE 1.0 or later.

Description & Usage

Sending the WM_CLOSE message to a window, naturally enough, instructs it to close. Some windows will prompt the user with a confirmation dialog box before it closes, while others will close immediately. Exactly what happens depends on the program. Just keep in mind that sending WM_CLOSE merely asks the window to close -- there's no guarantee that will actually happen.

Return Value

This message should always return zero.

Visual Basic-Specific Issues

None.

Parameters

wParam: Not used -- set to zero.
lParam: Not used -- set to zero.

Constant Definitions

Const WM_CLOSE = &H10

Example

Let the user enter the title of a window in a text box. Then, attempt to close the window whose title bar matches that text when the user clicks a button. To use this example, place a text boxed named txtTitle and a command button named cmdClose on a form window.

' This code is licensed according to the terms and conditions listed here.

' Declarations and such needed for the example:
' (Copy them to the (declarations) section of a module.)
Public Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA" (ByVal hWnd As Long, ByVal _
	Msg As Long, wParam As Any, lParam As Any) As Long
Public Const WM_CLOSE = &H10
Public Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" (ByVal lpClassName As String, _
	ByVal lpWindowName As String) As Long

' *** Place the following code inside the form window. ***

Private Sub cmdClose_Click ()
	Dim hWnd As Long  ' handle of the window to try to close
	Dim result As Long  ' result of the message
	
	' Get a handle to the window whose title the user entered.
	hWnd = FindWindow(vbNullString, txtTitle.Text)
	If hWnd <> 0 Then
		' Ask the window to close.
		result = SendMessage(hWnd, WM_CLOSE, ByVal CLng(0), ByVal CLng(0))
		Debug.Print "Told " & txtTitle.Text & " to close."
	Else
		' Couldn't find the window the user specified.
		Debug.Print "Unable to find window titled " & txtTitle.Text & "."
	End If
End Sub